Stupid OS/2 Tricks

Continuiamo in questo numero la traduzione della raccolta di tips & tricks di Melissa Woo trattando argomenti relativi alla Scrivania e alla WPS.

Sommario:

Salvataggio delle impostazioni della Scrivania senza chiudere il sistema

(Contributo di Jack Tan)

  1. Aprire il blocco impostazioni della Scrivania.
  2. Selezionare il separatore Finestra.
  3. Alla voce , cliccare su Creare nuova finestra.
  4. Chiudere il blocco impostazioni.
  5. Selezionare Aprire, Visualizzazione ad icone dal menu della Scrivania.
  6. Apparirà una nuova cartella della Scrivania, che eventualmente si può modificare come si desidera.
  7. Chiudere la nuova cartella della Scrivania, per salvare le sue impostazioni. La posizione delle icone sarà salvata.
  8. Cambiare nel blocco delle impostazioni della Scrivania, alla voce Visualizzazione oggetto già selezionato, in Visualizzare la finestra già esistente.
  9. Per rendere attivo i nuovi settaggi della cartella della Scrivania precedentemente creata, usare un'utility per terminare il secondo processo della PMSHELL. La Workplace Shell verrà riavviata con i nuovi settaggi.

Vedere anche Come ovviare ad un ordinamento accidentale delle icone della Scrivania

Cambiamento del colore del testo delle Copie collegate

Per cambiare il colore del testo delle Copie collegate:

  1. Aprire lo Schema correntemente usato dall'Elenco schemi.
  2. Selezionare Testo della copia collegata.
  3. Scegliere il colore desiderato nella tavolozza.
  4. Chiudere lo Schema appena editato.
  5. Trascinare lo Schema sulla cartella in cui sono contenute le Copie collegate di cui si vuole modificare il colore, premendo il tasto Alt nel caso si voglia modificare il colore del testo di tutte le Copie collegate contenute nel sistema.

Vedere anche Come cambiare il colore del testo di un'icona.

Spostamento delle icone

(contributo di Tim Sipples)

Per spostare un icona solo pochi pixel dalla posizione attuale, portare il puntatore del mouse sul bordo esterno dell'icona, nella direzione in cui si vuole effettuare lo spostamento, poi cliccare con il tasto destro e trascinare l'icona.

(Ndt) Nella versione 4.0 di OS/2 Warp questo non è più necessario.

Cambiamento automatico dello sfondo della Scrivania

(contributo di Jack Tan)

Lo sfondo della Scrivania può essere cambiato in modo casuale ad intervalli regolari tramite uno script REXX: 

/* BITMAP.CMD:  cambia lo sfondo della Scrivania ad intervalli regolari
   Sintassi:  BITMAP.CMD <intervallo in secondi> [/?]
   Copyright 1994 Jack Tan
*/
/* Controlla il valore dell'intervallo */
     arg interval
     if interval=="" | WORDPOS("/?", interval)<>0 then do
          SAY
          SAY "   BITMAP.CMD:  cambia casualmente lo sfondo della Scrivania"
          SAY "   ad intervalli periodici"
          SAY "   Sintassi:  BITMAP.CMD <intervallo in secondi> [/?]"
          SAY "   <intervallo> è l'intervallo tra due cambiamenti di sfondo",
              "in secondi."
          exit 1
     end  /* Do */
     else if DATATYPE(interval, "Whole Number")<>1 then
          call badNumber interval
     else if interval<=0 then
          call badNumber interval
/* Prepara per il cambiamento */
     signal on halt name exitProgram
     BootDrive  = VALUE("BOOTDRIVE", , "OS2ENVIRONMENT")
     BitmapSpec = BootDrive || "\OS2\BITMAP\*.BMP"
     call RxFuncAdd "SysLoadFuncs", "RexxUtil", "SysLoadFuncs"
     call SysLoadFuncs
     SAY "BITMAP.CMD:  Premere Ctrl+Break per terminare."
/* Esegue il cambiamento */
     do forever
          call SysFileTree BitmapSpec, "bitmaps", "FO"
          if bitmaps.0>0 then do
               i = RANDOM(1, bitmaps.0)
               call SysSetObjectData "<WP_DESKTOP>", "BACKGROUND="bitmaps.i";"
          end  /* Do */
          call SysSleep interval
     end /* Do */
exitProgram:

     SAY "             Terminato regolarmente"
     exit 0
badNumber: procedure
     SAY "Valore intervallo non valido '"ARG(1)"'"
     exit 2
Note: Lo script non supporta l'Affiancamento (tiling) delle bitmap e richiede che sia specificata la variabile di ambiente BOOTDRIVE: 
SET BOOTDRIVE=<drive:>
dove drive rappresenta il drive di boot di OS/2.

Cambiamento del puntatore del mouse

(contributo di Jack Tan e Dann Lunsford)

I vari puntatori del mouse possono essere facilmente cambiati usando questo script REXX: 

/* SetPtr.CMD -- set/remove a custom mouse pointer.
   Copyright 11 January 1994 by Jack Tan
   This is based on Dann Lunsford's SETMOUSE.CMD
       SETMOUSE.CMD by Dann Lunsford
       Short procedure to set mouse pointer to contents of specified .PTR file
       This file is in the public domain, but I'd appreciate it greatly if you
       would leave this notice in...     Author:  Dann Lunsford
                                                  Vortex BBS (1:203/726)
                                                  13-Aug-1993
   Be careful about adding/removing lines to this script -- it uses the
   SOURCELINE function, which is source-dependent.

   Syntax:  SetPtr.CMD <filename> [pointer index] [/X] [/L] [/?]

      <filename> is the name of the file containing the pointer.
         If <filename> does not exist, <filename>.PTR is searched.

      [pointer index] is an optional parameter.  It defaults to 1.
        Index  Pointer                       Default OS/2 icon
        ------------------------------------------------------------------
          1    normal OS/2 pointer           arrow
          2    text insertion                I-beam
          3    wait cursor                   clock
          4    size pointer                  (no icon)
          5    move pointer                  four-way arrow
          6    resize (NW to SE)             diagonal double arrow (\)
          7    resize (NE to SW)             diagonal double arrow (/)
          8    resize (horizontal)           horizontal double arrow (-)
          9    resize (vertical)             vertical double arrow (|)
      /X (optional) indicates that the custom pointer should be removed.
      /L (optional) lists currently installed pointers.
      /? (optional) displays this help.

*/

/* Get arguments */
   PARSE ARG arguments
   bigArgs = TRANSLATE(arguments)
/* Show help */
   if arguments=='' | WORDPOS("/?", arguments)<>0 then do
      do i=12 to 33
         SAY SOURCELINE(i)
      end /* do */
      EXIT(1)
   end  /* Do */
 /* Setup the REXX function */
   call RxFuncAdd 'SysIni', 'RexxUtil', 'SysIni'
   Inifile  = 'User'
   App      = 'PM_SysPointer'
/* Show current pointers */
   if WORDPOS('/L', bigArgs)<>0 then do
      result = SysIni(Inifile, App, 'All:', 'list')
      if list.0<1 then
         SAY "No custom pointers have been set."
      else do
         SAY "Current custom pointers:"
         do  i=1 to 9
            result = SysIni(Inifile, App, i)
            if result<>"ERROR:" then
               SAY "   ("i")" LEFT(pointerDesc(i), 20),
                  SUBSTR(result, 5, LENGTH(result)-5)
         end  /* Do */
      end  /* Do */
      EXIT(0)
   end  /* Do */
/* Look for a '/X' */
   xPos = WORDPOS('/X', bigArgs)
   if xPos<>0 then do
      removePtr = 1
      arguments = DELWORD(arguments, xPos, 1)
   end  /* Do */
   else
      removePtr = 0
/* Look for a pointer index */
   pointerIndex = 1
   if WORDS(arguments)>1 | removePtr then do
      /* Last argument should be the pointer index, since any '/X'
         has already been removed.  If the last argument does not fit
         the requirements for a pointer index, assume that it is part
         of the filename.
      */
      guessIndex = WORD(arguments, WORDS(arguments))
      if LENGTH(guessIndex)==1 & VERIFY(guessIndex, '123456789')==0 then do
         arguments = DELWORD(arguments, WORDS(arguments))
         pointerIndex = guessIndex
      end /* Do */
   end  /* Do */
/* Set the filename */
   if removePtr<>1 then do
      arguments = STRIP(arguments)
      if SUBSTR(arguments, 1, 1)=='"' then
         arguments = DELSTR(arguments, 1, 1)
      if SUBSTR(arguments, LENGTH(arguments))=='"' then
         arguments = DELSTR(arguments, LENGTH(arguments))
      filename = STREAM(arguments, 'Command', 'Query Exists')
      if filename=='' then do
         /* Try again use .PTR extension */
         filename = STREAM(arguments".PTR", 'Command', 'Query Exists')
         if filename=='' then do
            SAY "Cannot find file:  '"arguments"'"
            EXIT(3)
         end  /* Do */
      end  /* Do */
   end  /* Do */
/* Execute the change */
   if removePtr then
      result = SysIni(Inifile, App, pointerIndex, 'DELETE:')
   else do
      Keyvalue = x2c('01000000')||filename||x2c('00')
      result = SysIni(Inifile, App, pointerIndex, Keyvalue)
   end  /* Do */
/* If the change failed... */
   if result<>"" then do
      returnCode = 3
      if removePtr then
         SAY "Unable to delete the pointer"
      else
         SAY "Unable to set the pointer"
   end  /* Do */
/* ... else print 'successful' message */
   else do
      returnCode = 0
      if removePtr then
         SAY "Pointer successfully removed"
      else
         SAY "The new pointer will become effective at the next system boot."
   end  /* Do */
/* Give some more information */
   if removePtr<>1 then
      SAY "   File    = "filename
   SAY "   Pointer = "pointerDesc(pointerIndex) "("pointerIndex")"
EXIT(returnCode)
pointerDesc: procedure
   return STRIP(SUBSTR(SOURCELINE(20+ARG(1)), 15, 30))
/* End of REXX script */
  1. Per creare dei nuovi pointer usare l'editor di icone.
  2. Per maggiori informazioni avviare lo script senza parametri.
  3. Non cancellare il file PTR dopo che è stato assegnato come puntatore del mouse: altrimenti non potrà più essere possibile riavviare il sistema.

(Ndt) Per cambiare i puntatori del mouse in OS/2 Warp:

  1. Aprire la cartella Impostazione del sistema.
  2. Aprire l'oggetto Mouse.
  3. Selezionare il separatore Puntatori dal Blocco impostazioni.
  4. Cliccare sul puntatore che si desidera modificare, o trascinare nella finestra Puntatori di sistema un file PTR con lo stesso nome del puntatore che si vuole sostituire.
  5. Nel caso si voglia sostituire un intero set di puntatori, dopo aver creato con l'editor d'icone un set di pointer con lo stesso nome dei pointer originali (vedere nella cartella \os2\pointers) trascinare la cartella che li contiene nella finestra Puntatori di sistema.
.

Come far apparire una finestra di richiesta parametri

Per far si che vengano richiesti i parametri quando si avvia un programma:

  1. Aprire il blocco impostazioni del programma.
  2. Nel campo Parametri introdurre due parentesi quadre: [ ].
  3. Se si vuole far apparire del testo, nella finestra di richiesta dei parametri, scriverlo all'interno delle parentesi quadre.

Come trovare un'icona coperta

Quando si hanno molte finestre aperte sulla Scrivania e si vuole accedere ad un'icona coperta da queste finestre:

  1. Cliccare con il tasto destro del mouse su uno spazio della Scrivania.
  2. Selezionare dal menu della Scrivania Aprire, Visualizzazione dettagli.
  3. Se nel Blocco impostazioni della Scrivania, nella pagina Finestra si è selezionato, nel campo Visualizzazione oggetto già selezionato, Creare nuova finestra, è possibile selezionare dal menu della Scrivania anche la voce Aprire, Visualizzazione ad icone.

(Ndt) In OS/2 Warp 4.0 è possibile chiudere tutte le finestre aperte selezionando la Scrivania dall'elenco dei task attivi del Warp Center.

Come cambiare il colore del testo di un'icona

  1. Aprire la Tavolozza dei colori nella cartella Impostazione del sistema.
  2. Trascianare il colore prescelto sull'icona tenendo contemporaneamente premuto il tasto Ctrl.

Come ovviare ad un "Riordinare" accidentale delle icone della Scrivania

Se involontariamente si è cambiata la disposizione delle icone sulla Scrivania, tramite la voce Riordinare del menu, si può usare un'utility per terminare la seconda istanza della PMSHELL. La Scrivania verrà riavviata con le icone nella posizione precedente.

(Ndt) In OS/2 WARP, dopo che si è effettuato un riordinamento, nel menu appare la voce Annullare riordinio che permette di ripristinare la precedente posizione delle icone.
È inoltre possibile installare NPS WPS Enhancer facendogli rimuovere le voci Ordinare e Riordinare dal menu della Scrivania, o, nel caso non si vogliano usare utility esterne, riavviare il sistema con Ctrl-Alt-Del dopo aver salvato e chiuso i file aperti.

Come creare una Tool bar

Si può fare in modo che una normale cartella funzioni da tool bar:

  1. Creare una nuova cartella.
  2. Dimensionarla e posizionarla dove si preferisce.
  3. Impostare la posizione delle icone in una colonna.
  4. Creare nella cartella Copie collegate delle applicazioni usate più di frequente.
  5. Creare una copia collegata della nuova cartella nella cartella Avviamento così che la cartella venga aperta automaticamente ogni volta che si avvia il sistema.

(Ndt) Con OS/2 versione 3.0 e successive è preferibile usare il Pannello di avvio.

Come creare un Trash Can

(contributo di Chris Corzine)

Si può modificare facilmente una cartella in modo da farla funzionare da trash can:

  1. Creare una subdirectory chiamata TrashCan e dotarla di un'opportuna icona.
  2. Creare sulla Scrivania una copia collegata della subdirectory TrashCan o collocarla sul Pannello di avvio (è opportuno che la subdirectory Trashcan non sia una subdirectory della Scrivania per evitare che i programmi che salvano la configurazione del sistema non salvino anche il contenuto del TrashCan).
  3. Creare un semplice file batch EMPTRASH.CMD per lo svuotamento del TrashCan: 
    @ECHO OFF
DEL <drive:><path>TrashCan
    sostituendo gli opportuni valori a <drive:> e <path>.
  4. Aggiungere il comando EMPTRASH al menu della cartella, (trascinandolo sulla finestra di configurazione del menu del Blocco impostazioni della cartella stessa) e/o inserirlo nel cassetto del Pannello di avvio sopra all'icona del TrashCan.
  5. Per cancellare uno o più file è sufficiente trascinarli nella cartella TrashCan, che periodicamente si svuoterà tramite EMPTRASH.CMD.

Come selezionare gli oggetti senza il mouse

Per selezionare gli oggetti contenuti in una cartella senza usare il mouse, digitare la prima lettera dell'oggetto e premere Invio per aprire l'oggetto. Se sono presenti più oggetti che iniziano con la stessa lettera, premere ripetutamente la stessa lettera fino a selezionare l'oggetto desiderato.

Come nascondere una cartella

Per rendere invisibile una cartella contenuta nella Scrivania:

  1. Aprire il Blocco impostazioni della cartella.
  2. Selezionare il separatore File.
  3. Selezionare il check box Nascosto del gruppo Attributi.

Per renderla nuovamente visibile:

  1. Aprire il Blocco impostazioni della Scrivania.
  2. Selezionare il separatore Includere.
  3. Cliccare sul pulsante Modificare.
  4. Nella dialog box che appare selezionare:
    1. Attributo: Attributi
    2. Tipo di confronto: è diverso da
    3. Valore di confronto: H
  5. Cliccare su Modificare.
  6. Chiudere il Blocco impostazioni.

(Ndt) È possibile anche usare dalla riga di comando il comando ATTRIB, sia per impostare l'attributo HIDDEN che per resettarlo e rendere nuovamente visibile la cartella.

Come creare un oggetto di editazione dei file di sistema

È possibile creare un oggetto che apre automaticamente per l'editazione i file di sistema, sfruttando le proprietà delle cartelle Area di lavoro.

  1. Creare una nuova cartella.
  2. Aprire il Blocco impostazioni e selezionare il separatore File.
  3. Selezionare il check box Area di lavoro e chiudere il Blocco impostazioni.
  4. Creare nella nuova cartella delle copie collegate dei file CONFIG.SYS, WIN.INI, SYSTEM.INI e AUTOEXEC.BAT.
  5. Aprire la nuova cartella ed avviare dal menu dei vari oggetti l'Editor dell'OS/2.
  6. Chiudere la nuova cartella senza chiudere le finestre aperte: queste verranno chiuse automaticamente dalla cartella.
  7. Ogni volta che si aprirà la cartella così creata, verranno aperte automaticamente delle finestre di editazione dei file di sistema.

Associazione dei file di dati ad un programma

Per far sì che un file venga aperto dalla giusta applicazione, a volte, è necessario definire esplicitamente l'associazione nel blocco impostazioni dell'applicazione:

  1. Aprire il Blocco impostazioni dell'applicazione.
  2. Selezionare il separatore Associazione
  3. Se il tipo di file che si vuole associare è nell'elenco dei Tipi disponobili, selezionarlo e cliccare su Aggiungere>>.
  4. Nel caso contrario del i file che si vogliono associare hanno un'estensione o nome comune inserirla nel campo Nuovo nome: con gli opportuni caratteri jolly e cliccare sul pulsante Aggiungere>>.
  5. Se i file non hanno un nome o un'estensione comuni sarà necessario impostare l'associazione nel Blocco impostazioni dei singoli file.

Creazione di nuovi oggetti stampante

Per creare un nuovo oggetto stampante:

  1. Aprire la cartella Maschere.
  2. Trascinare nella cartella desiderata un oggetto dalla maschera della stampante.
  3. Personalizzare le impostazioni del nuovo oggetto stampante.

Creazione di nuovi template (maschere)

È possibile creare delle maschere personalizzate. Per esempio si può creare un template di un file di un word processor che contenga lo schema base per una lettera commerciale, così che la prossima volta che serve un tale tipo di lettera sia sufficiente trascinarne una copia dalla maschera e personalizzarla come sarà opportuno.

  1. Dopo aver creato il file con gli elementi che saranno comuni a tutti i file che si vogliono derivare da esso, salvarlo nella cartella maschere o dove si riterrà opportuno.
  2. Aprire il blocco impostazioni del file appena creato.
  3. Selezionare il separatore Generale.
  4. Selezionare la check box Maschera e chiudere l'oggetto.
  5. Ogni volta che sarà necessario un file simile basterà crearne uno trascinandolo dalla cartella maschere.

Ripristino dell'oggetto trinciatrice cancellato accidentalmente

Nel caso sia stata accidentalmente cancellata la trinciatrice, è possibile ricrearla con un semplice file REXX: 

/* shredder.cmd - REXX script to recreate the Shredder */
call RxFuncAdd "SysCreateObject", "RexxUtil", "SysCreateObject"
class="WPShredder"
title="Trinciatrice"
location="<WP_DESKTOP>"
settings="OBJECTID=<WP_SHRED>;"
settings=settings||"ICONPOS=90 8;"

call SysCreateObject class, title, location, settings, "REPLACE"
exit
Se l'oggetto Trinciatrice è già presente nel sistema, questo verrà sovrascritto dal nuovo oggetto.

(Ndt) È possibile modificare lo script, ricavando dal file INI.RC, contenuto nella directory OS2, i parametri necessari, per ricreare altri oggetti cancellati accidentalmente.

Gestione dei file di icona

(contributo di George Orvis)

Nel caso si abbiano molti file icona, per gestirli più comodamente:

  1. Spostare tutti file in una directory o se numerosi in diverse subdirectory suddividendoli in modo logico secondo l'oggetto rappresentato.
  2. Creare, nel caso si acceda spesso ai file, una copia collegata della cartella sulla Scrivania.
  3. Dal Blocco impostazioni della cartella, separatore Menu, selezionare come azione di default di apertura della cartella Visualizzazione a icone.
  4. Se si usa una release recente di OS/2 Warp si può deselezionare la check Visibile nel riquadro Test icona.
  5. Per editare un'icona cliccare su essa.
  6. Per cambiare l'icona di un oggetto:
    1. Aprire il Blocco impostazioni dell'oggetto.
    2. Selezionare il separatore Generale.
    3. Trascinare nel riquadro Icona corrente un'icona scelta tra quelle presenti nella cartella delle icone.
    4. Chiudere il Blocco impostazioni.

Editazione dei nomi degli oggetti

Per cambiare il nome di un oggetto:

(contributo di Rob Targosz e Jack Tan)

  1. Selezionare l'icona e premere Maiuscolo-F9, oppure premere Alt e cliccare con il tasto 1 del mouse sul testo dell'icona.
  2. Editare il testo dell'icona.
  3. Per chiudere il campo di editazione, cliccare con il mouse nella cartella in cui è contenuta l'icona o premere il tasto Invio del tastierino numerico. Il tasto Invio principale serve per spezzare il titolo dell'icona su più righe.

Spostamento di un oggetto template (maschera)

(contributo di Nathan Hamblen)

Per spostare un oggetto template senza creare un nuovo oggetto, mantenere premuto il pulsante Maiuscolo durante il trascinamento.

Cambiamento del "LONGNAME" di un oggetto senza cambiare il nome reale

(contributo di Bill Parrill)

Il LONGNAME o testo dell'icona di un oggetto può essere modificato, senza che questo comporti il cambiamento del nome del file fisico, con un semplice script REXX: 

/* Questa procedura cambia il LONGNAME di un     */
/* file senza cambiare il vero nome del file.    */
/* Uso:                                          */
/*    PUTLONG myfil.ext "Long File Name"         */
/* copyright Bill Parrill                        */
/* bparrill@vnet.ibm.com                         */

call RxFuncAdd 'SysPutEA', 'RexxUtil', 'SysPutEA'

parse arg FileName '"'LongName'"'

if FileName = '' then DO
   say ' Specificare il nome di un file!'
   exit 1
   end  /* Do */

if LongName = '' then DO
   say ' Specificare il LONGNAME!'
   exit 2
   end  /* Do */

say 'File Name: 'FileName
say 'LONGNAME: 'LongName
RetCode = SysPutEA(FileName, '.LONGNAME',,
                   'FDFF'x||D2C(LENGTH(LongName))||'00'x||LongName)
say 'Return Code: 'RetCode

EXIT

Aggiunta di file INF al menu della Scrivania

I file con estensione INF sono consultabili tramite il programma VIEW.EXE. Se si vuole aggiungere un file INF al menu della scrivania (o di un'altra cartella) è necessario creare prima un oggetto programma:

  1. Creazione di un oggetto file INF:
    1. Aprire la cartella Maschere e trascinare un oggetto programma nella cartella desiderata.
    2. Nella pagina Programma, nel campo Percorso e nome file: scrivere: VIEW.EXE.
    3. Nel campo Parametri scrivere il nome e il percorso del file INF, seguiti da uno spazio e un segno di percentuale (%).
    4. Chiudere il Blocco impostazioni del nuovo oggetto.
  2. Aggiunta dell'oggetto file INF al menu della Scrivania:
    1. Aprire il Blocco impostazioni della Scrivania.
    2. Selezionare il separatore Menu.
    3. Trascinare con il tasto 2 del mouse l'oggetto INF nella list box Azioni sul menu:.
    4. Chiudere il Blocco impostazioni.
  3. Ora la voce relativa all'oggetto INF sarà presente nel menu della Scrivania.

Come ricreare un template (maschera) cancellato accidentalmente

(contributo di Jack Tan)

Per ricreare un template cancellato accidentalmente:

  1. Trovare un oggetto dello stesso tipo di quello di cui si è perso il template.
  2. Far apparire il menu contestuale dell'oggetto premendo il tasto 2 del mouse.
  3. Selezionare Creare un altro.
  4. Aprire il Blocco impostazioni del nuovo oggetto.
  5. Selezionare il separatore Generale.
  6. Selezionare il check box Maschera.
  7. Chiudere il Blocco impostazioni.
  8. Il nuovo oggetto è una maschera.

Associazione di un'icona con un file eseguibile

(contributo di Jack Tan)

Per associare un icona ad un file eseguibile:

  1. Copiare il file icona nella stessa directory in cui è collocato l'eseguibile.
  2. Rinominare il file icona in modo che abbia lo stesso nome dell'eseguibile, tranne l'estensione ICO.

Riduzione dei menu

(contributo di Jack Tan)

Per ridurre il numero delle voci presenti nei menu di sistema degli oggetti aggiungere nel CONFIG.SYS: 

SET MENUSTYLE=SHORT
Molte voci verranno rimosse come: Aiuto, Creare un altro, Creare copia collegata..., Copiare, Spostare, Cancellare, Ricercare.

Rimozione dell'oggetto Drive B

(contributo di Timur Tabi)

Se si ha un solo floppy e si vuole eliminare l'oggetto drive B si può seguire il seguente metodo:

  1. Aprire il Blocco impostazioni della cartella Unità.
  2. Selezionare il separatore Includere.
  3. Cliccare sul pulsante Modificare
  4. Nella finestra Modificare i criteri:
    1. Nel campo Attributo: selezionare Titolo oggetto.
    2. Nel campo Tipo di confronto selezionare è uguale a.
    3. Nel campo Valore di confronto scrivere il nome dell'oggetto: Unità B.
    4. Nel riquadro Uso dei criteri cliccare sul radio button E - escludere.
  5. Chiudere il Blocco impostazioni.

Creazione di un oggetto programma

(contributo di Timur Tabi)

  1. Copiare e salvare lo script REXX PROGRAM.CMD: 
    /* program.cmd */
Call RxFuncAdd 'SysLoadFuncs','RexxUtil','SysLoadFuncs'
Call SysLoadFuncs
Parse Arg FileName Title
slash=lastpos("\",FileName);
if slash=3 then slash=4
Startup=left(filename,slash-1)
rc=SysCreateObject("WPProgram",,
  Title,,
  "<WP_DESKTOP>",,
   "EXENAME="FileName";STARTUPDIR="Startup)
  2. Creare un oggetto programma chiamato Creare nuovo oggetto.
  3. Nel campo Percorso e nome file: scrivere il nome e il percorso di PROGRAM.CMD.
  4. Nel campo Parametri scrivere: 
    %* [Introdurre il nome del nuovo oggetto]
  5. Selezionare il separatore Sessione.
  6. Selezionare la check box Avvio ridotte al minimo.
  7. Selezionare il separatore Associazione.
  8. Nel campo Nuovo nome: aggiungere *.EXE e cliccare sul pulsante Aggiungere>>.
  9. Ripetere la procedura specificando *.CMD, *.BAT e *.CPM.
  10. Chiudere il Blocco impostazioni.
  11. Ogni file eseguibile ora avrà nel submenu della voce Aprire la voce Creare nuovo oggetto. Sarà anche possibile creare un nuovo oggetto trascinando l'icona di un programma su quella dell'oggetto Creare nuovo oggetto.
a cura di Alessandro Cantatore
Pagina
precedente 		Home Page Sommario Pagina
successiva